// HC-SR04 com Arduino — versão robusta
// Mamute Eletrônica | blog.mamuteeletronica.com.br

#define TRIG_PIN  9
#define ECHO_PIN  10
#define TIMEOUT   30000  // 30 ms → ~5 m máximo

void setup() {
  Serial.begin(9600);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
}

float lerDistancia() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  long dur = pulseIn(ECHO_PIN, HIGH, TIMEOUT);
  if (dur == 0) return -1;
  float d = dur / 58.0;
  return (d < 2.0) ? -1 : d;
}

float lerMediana(int n) {
  float v[n];
  for (int i=0;i<n;i++) { v[i]=lerDistancia(); delay(25); }
  for (int i=0;i<n-1;i++)
    for (int j=0;j<n-i-1;j++)
      if (v[j]>v[j+1]) { float t=v[j]; v[j]=v[j+1]; v[j+1]=t; }
  return v[n/2];
}

void loop() {
  float dist = lerMediana(5);
  if (dist < 0) Serial.println("Fora do alcance");
  else { Serial.print("Distância: "); Serial.print(dist,1); Serial.println(" cm"); }
  delay(500);
}

// HC-SR04 com ESP32 — divisor de tensão no ECHO
// VCC → VIN (5V) | ECHO → R1(1kΩ)+R2(2kΩ) → GPIO

#define TRIG_PIN   5
#define ECHO_PIN   18  // com divisor de tensão!
#define TIMEOUT    30000

void setup() {
  Serial.begin(115200);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
}

float lerDistancia() {
  digitalWrite(TRIG_PIN, LOW);  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH); delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  long dur = pulseIn(ECHO_PIN, HIGH, TIMEOUT);
  if (dur==0) return -1;
  float d = dur/58.0;
  return (d<2.0||d>400.0) ? -1 : d;
}

void loop() {
  float dist = lerDistancia();
  if (dist<0) Serial.println("Sem objeto no alcance");
  else Serial.printf("Distância: %.1f cm\n", dist);
  delay(500);
}